Rankia España Rankia Argentina Rankia Brasil Rankia Chile Rankia Colombia Rankia Czechia Rankia Deutschland Rankia France Rankia Indonesia Rankia Italia Rankia Magyarország Rankia México Rankia Netherlands Rankia Perú Rankia Polska Rankia Portugal Rankia Romania Rankia Türkiye Rankia United Kingdom Rankia USA
Acceder

Trucos y tretas en Excel VBA para programadores

Este post no está hecho para novatos que no sepan nada del macros de Excel, sino aquellos que saben algo de programación de Visual Basic. Si eres neófito en macros de Excel en Visual Basic, deberías ver mi post Excel VBA y macros: Una herramienta muy útil para trabajar hojas de cálculo (1).  Me han de perdonar la manera en que aparece el código, pero es un problema en la manera en que aparece el código HTML para desplegar código con indentación en este sitio.

Especialmente en finanzas o en bolsa, pero también en negocios de todo tipo, programar macros de Excel suele ser sumemante útil y por eso he querido deicar este post a transmitir algunos trucos para ahorrarte tiempo.  Cuando programamos código para macros de Excel VBA a menudo nos encontramos con que los detalles de cómo invocar tal o cual cosa de Excel termina siendo muy críptica y debes navegar por foros, tutoriales o incontables páginas ininteligibles de Microsoft que no te responden lo que andas buscando.

Si sabes Visual Basic, lo más lógico es que para elaborar macros, trates de grabar una macro primero, y luego empiezas a ver el código de muestra para ver cómo hacer determinadas cosas.  En este post se pretende proveer trucos de programación en Excel VBA para efectuar tareas que no se pueden derivar del código grabado en una macro en Excel.  Estos trucos son el resultado de resolver una serie de problemas que en su momento significaron un dolor de cabeza.

Obtener valor de una celda


    Cells(4,5)=23
    x = Cells(4,5)+1

Este ejemplo inserta el valor 23 en la celda de la fila 4 y columna 5.  Luego la variable x toma ese valor y le suma 1.  Cabe añadir que cada vez que llamamos una celda, una cantidad muy grande de código de Excel es invocada, de modo que si piensas trabajar con muchas celdas o muchas veces con la misma celda, es mejor que pases los valores a variables, en lugar de llamar a la celda en sí misma.

    Cells(2,3).Select
    Selection.HorizontalAlignment = xlCenter
    Selection.VerticalAlignment = xlCenter

En este ejemplo, la celda de la fila 2 columna 3 es seleccionada, y la selección luego es objeto de centrado vertical y horizontal usando Selection.

Usando rangos

Pasar de la notación de fila y columna a la de celdas suele ser un poco incómodo.  Normalmente para seleccionar un rango usaríamos algo como esto:


    Range("A5:B8").Select

Como has visto, lo que está procesando la función Range() entre comillas es una hilera de caracteres. Para efectos de escribir código, podemos usar esta expresión equivalente:


    Range(Cells(5,1),Cells(8,2)).Select

Convertir números en letras (pasar de la notación fila 5 columna 1 a "A5") suele ser sumamente incómodo. Para ello he construido una función que hace el trabajo.


  Private Function GetColumnLetter(index) As String
    Dim FL, LL As Long
    
    GetColumnLetter = ""
    LL = (index - 1) Mod 26 + 65
    If LL > 63 Then GetColumnLetter = Chr(LL)
    If index > 26 Then
        FL = Int((index - 1) / 26) + 64
        GetColumnLetter = Chr(FL) & GetColumnLetter
    End If

  End Function

La función convierte el número en letras, en caracteres. Cabe anotar que sólo sirve para llegar hasta columna ZZ, de modo que si se pasa de esa columna, esta función no te servirá. Para llamar esta función con las mismas coordenadas (5,1) y (8,2) harías algo como esto para convertir en hilera:


  Range(GetColumnLetter(5) & Format(1,"0") & ":" & GetColumnLetter(8) & Format(2,"0")).Select

Como habrás notado he usado la función Format() que evita que se agreguen espacios al convertir de número a hilera, como pasaría con la función Str().

Ventana emergente para que el usuario ingrese un rango

 

Si quieres que aparezca una ventana emergente con la cual puedas pedir al usuario que seleccione un rango de datos, puedes usar el código que se muestra a continuación.  Lo que se hace es declarar un objeto de tipo Range llamado celdasSeleccionadas.  A ese objeto se le asigna el resultado de la función Application.InputBox que despliega la ventana emergente que solicita la información al usuario.  Si el usuario no ingresa ningún rango, el valor que tendrá el objeto es Nothing.

El comando On Error Resume Next indica que si ocurre un error, entonces ignore el error y proceda conla siguiente instrucción. El comando On Error Goto 0 indica que se cancela la detección de errores.  El comando Msgbox despliega información en una ventana emergente.

He aquí el código:


    Dim celdasSeleccionadas As Range
    
    On Error Resume Next
    Set celdasSeleccionadas = Application.InputBox(prompt:="Seleccione un rango de celdas", Type:=8)
    On Error GoTo 0
    If celdasSeleccionadas Is Nothing Then
        'Aquí va el código que se ejecuta si no se selecciona ninguna celda.
        'En este caso se despliega una ventana emergente con un mensaje.
        MsgBox "No se ha seleccionado ninguna celda."
    Else
        'Aquí va el código que se ejecuta si se se seleccionó celdas.
        'En este caso se despliega una ventana emergente con el resultado de la suma de celdas.
        MsgBox Application.WorksheetFunction.Sum(celdasSeleccionadas.Cells)
    End If

Como habrás notado en este código lo que se hace si el usuario digita un código es desplegar el valor de la suma de todos los valores del rango usando la función Application.WorksheetFunction.Sum, pero tú puedes hacer que haga algo distinto.

Si quisieras obtener el valor contenido en el rango seleccionado puedes usar este código.


    MiVariable = celdasSeleccionadas.Value

En este caso el contenido del rango se almacena en una variable llamada MiVariable.

Acelerar la ejecución

Cuando un programa corre, todo lo que tiene que ver con actualización de pantalla es sumamente lento, y lo mejor es desconectar toda actualización de video.  Para ello debes agregar el siguiente código al inicio de la macro.


    Application.ScreenUpdating = False
    Application.DisplayStatusBar = True
    Application.StatusBar = "Iniciando..."

Y este código al final.


    Application.ScreenUpdating = True
    Application.StatusBar = "Ejecución terminada."

Application.ScreenUpdating se encarga de encender y apagar la actualización de video. Application.DisplayStatusBar = True habilita la barra de estado que está en la parte inferior de la ventana de Excel, y allí despliegas mensajes asignando una hilera a Application.StatusBar. La idea de usar la barra de estado es que si la ejecución de la macro tarda mucho, es bueno que el usuario sepa que la macro está trabajando, y que no se ha quedado atascada. 

No hay nada que fastidie más que tener un programa atascado frente a uno.  Por eso sería bueno que dentro de la macro agregues otros mensajes donde el usuario pueda ver que la macro va caminando, pero si pones mensajes con demasiada frecuencia eso ralentizará la ejecución, porque como dijimos, la actualización de video consume mucho tiempo de la máquina.

Esto es especialmente útil cuando vas a correr una macro que pasa de un libro de Excel a otro o que se mueve mucho a lo largo de las páginas o celdas de manera muy intensiva.

Obtener posición de la última celda

Cuando tienes hojas de Excel de tamaño variable y necesitas ubicar la última celda ocupada (la que está más abajo y más a la derecha), puedes usar lo siguiente:


    ActiveCell.SpecialCells(xlLastCell).Select
    UltimaFila = ActiveCell.Row
    UltimaColumna = ActiveCell.Column

Si buscas en Internet acerca de cómo obtener posición de la última celda, encontrarás maneras muy diversas.  Sin embargo, esta es la mejor que he encontrado.  Si agregas valores más allá de la última celda, el valor se actualiza.  El único problema es que si borras filas o columnas, este número no cambiará, sino hasta que abras de nuevo el archivo de Excel.  Sin embargo eso es mejor que nada, y puedes verificar si encuentras celdas en blanco, así que eso no debería ser problema.

Obtener los nombres de libros de Excel abiertos.

En ocasiones ocupas una lista de los libros de Excel que están abiertos.  Para ello te vales del objeto Workbooks de Excel.


    Dim NombreDeArchivo() as String

    Redim NombreDeArchivo(Workbooks.Count-1)
    For i = 1 To Workbooks.Count
        NombreDeArchivo(i-1) = Workbooks.Item(i).Name
    Next i

El arreglo NombreDeArchivo almacenará los nombres de los archivos de Excel que están abiertos en un momento dado.

Obtener la lista de páginas del libro de Excel

Puedes usar el siguiente código.


    Dim NombreDePagina()
    Dim Cantidad as Long

    Cantidad = Sheets.Count
    redim NombreDePagina(n)
    For i = 1 To Cantidad 
        NombreDePagina(i) = Sheets(i).Name 
    Next i 

Los nombres se almacenan en el arreglo NombreDePagina.

Obtener los nombres de las gráficas (charts) que hay en una página de Excel

Hay ocasiones en que ocupas buscar todas las gráficas contenidas en una página de Excel.  para ello te vales de ActiveSheet.ChartObjects


    Dim NombreDeChart()

    Redim NombreDeChart(ActiveSheet.ChartObjects.Count-1)
    For i = 1 To ActiveSheet.ChartObjects.Count
        NombreDeChart(i-1) = ActiveSheet.ChartObjects(i).Name
    Next i

El arreglo NombreDeChart contendrá los nombres de las gráficas de la hoja de Excel en que nos encontramos.

Obtener el nombre del libro de Excel en que te encuentras actualmente

Existen algunas situaciones donde ocupas saber el nombre del libro de Excel en que te encuentras actualmente.


    LibroActual = ActiveWorkbook.Name

El nombre de la hoja actual será guardado en la variable LibroActual.

Cambiar de libro o de hoja

Si deseas pasarte a otro libro abierto u otra hoja, puedes usar el siguiente código.


    Workbooks("MiLibro.xls").Activate
    Sheets("Sheet1").Select

Este código hará que te pases al libro de Excel MiLibro.xls y a la página Sheet1 de ese libro. Como ves, el valor entre comillas puede ser reemplazado por una variable tipo String si lo deseas.

Cómo lidiar con libros de Excel protegidos por password


    If ActiveSheet.ProtectContents Then
        ActiveSheet.Unprotect Password:="XYZ"
    End If

Este código se encargará de eliminar la protección contra password.  En este caso el password es XYZ.  Cuando trabajas con hojas protegidas con password, obtendrás errores al tratar de acceder a material protegido y por eso debes desproteger la hoja para trabajar en ella.

Enviar un correo con archivo adjunto

Si quieres generar un correo y pegarle un archivo adjunto, puedes usar el siguiente código:


    Dim oLook As Object
    Dim oMail As Object
    
    Set oLook = CreateObject("Outlook.Application")
    Set oMail = oLook.createitem(0)
    With oMail
        .To = "[email protected]"
        .body = "Este es el cuerpo del mensaje. Ver archivo adjunto"
        .Subject = "Asunto. Envio de archivo adjunto"
        .Attachments.Add ("C:\MiArchivo.xlsx")
        .Send
    End With
   
    Set oMail = Nothing
    Set oLook = Nothing

Este código buscará el archivo MiArchivo.xlsx ubicado en C:\, construirá el mensaje y lo enviará a la dirección [email protected].  La lógica de este código usa un poco de programación orientada a objetos.  oLook es un objeto que se encarga de manejar la aplicación Outlook, y oMail es un objeto que se encarga de manejar el correo.

Ocultar una hoja e impedir que el usuario la vea

Si quieres ocultar una hoja de Excel para que el usuario no la pueda ver, y no pueda mostrar su contenido usa este código:


    Set hide_sheet = Sheet1
    hide_sheet.Columns.Hidden = True
    hide_sheet.Visible = False

El código lo que hace es ocultar todas las columnas de la hoja Sheet1 y luego oculta la hoja.  Cabe notar que Sheet1 no es el nombre de la hoja visible para el usuario, sino el nombre del objeto que aparece en el editor de código de Excel VBA fuera de los paréntesis.

Crear un botón en una hoja de cálculo

Si quieres crear un botón:

   ActiveSheet.Buttons.Add ActiveCell.Left, ActiveCell.Top, ActiveCell.Width, ActiveCell.Height

El código crea un botón sobre la celda en la que estás ubicado actualmente.

Cargar, refrescar, salvar y cerrar una hoja de cálculo

Si quieres efectuar esas tareas:


    Workbooks.Open Filename:="C:\MiArchivo.xlsx", UpdateLinks:=3
    Workbooks("MiArchivo.xlsx").RefreshAll
    ActiveWorkbook.Save
    ActiveWindow.Close

El código efectúa las cuatro tareas descritas en ese orden.

Cómo usar el portapapeles

El portapapeles no viene incluido en la versión básica de Excel VBA, así que primero tenemos que configurar algunas cosas.  

  • Ve al editor de Visual Basic (Alt F11).
  • Selecciona Tools > References


     
  • Activa Microsoft Forms Object Library y presiona Ok.

Si no aparece Microsoft Forms 2.0 Object Library en la lista, quizás quieras usar el botón Browse para buscar el archivo FM20.DLL que se encuentra en la ubicación en disco duro que se muestra en la imagen.

Ahora que ya configuramos todo, veamos el código.
Primero deberías declarar el objeto de portapapeles (en este caso le llamaremos doClip)

    Dim doClip As DataObject

Este sería el método para crear el portapapeles en memoria.

    Sub CrearClipboard()
        Set doClip = New DataObject
    End Sub

 

Con este método puedes destruir el objeto portapapeles en memoria para liberar espacio.

    Sub DestruirClipboard()
        Set doClip = Nothing
    End Sub

 

Con este método copias un texto al portapapeles.


    Sub CopiarAlClipboard(sTexto As String)
        doClip.Clear
        doClip.SetText sTexto
        doClip.PutInClipboard
    End Sub

Con esta función extraes el texto del portapapeles. 


    Function ClipboardTexto() As String
        doClip.GetFromClipboard
        ClipboardTexto = doClip.GetText
    End Function

Cómo configurar área de impresión

Para configurar el área de impresión ocupas la orientación portrait o landscape.  He puesto las muestras de las líneas para ambos casos, aunque tú sólo ocuparías una.  Si vas a ajustar a una o más páginas horizontal o verticamente, primero necesitas poner el modo Zoom en apagado y luego puedes configurar los ajustes.  Y también debes delimitar el área de impresión que en este ejemplo es desde A1 hasta H25.


    ActiveSheet.PageSetup.Orientation = xlPortrait
    ActiveSheet.PageSetup.Orientation = xlLandscape

    ActiveSheet.PageSetup.Zoom = False
    ActiveSheet.PageSetup.FitToPagesWide = 1
    ActiveSheet.PageSetup.FitToPagesTall = 1
    ActiveSheet.PageSetup.PrintArea = "A1:H25"

Cómo crear una lista de archivos y directorios

Para obtener una lista de archivos, ve al siguiente sitio:  List all files in a directory.

Para listar archivos y subdirectorios ve al sitio List folders and subdirectories.

Otros trucos

Existen trucos para optimizar el desempeño de Visual Basic, tales como:

  • Evitar al máximo el uso de propiedades de controles.  Las celdas de Excel son controles. Los forms (formulario, ventana) y los controles sobre un form son controles. Usar propiedades de controles agrega mucha carga de procesamiento innecesario.  Por ejemplo, el valor de una celda es una propiedad del control llamado celda.  El texto de un control de texto es una propiedad. Hay que minimizar la referencia a controles hasta donde sea posible, pasando los valores de los controles a una variable, se trabaja todo en la variable, y al final se actualiza la propiedad del control con el valor final de la variable.
  • Apaga la actualización de video, porque el tiempo de actualizar la pantalla innecesariamente consume enormes cantidades de tiempo de procesamiento.
  • Evitar el uso de variables tipo Variant.  Estas variables generalmente aparecen cuando no se declaran las variables.  Para hacer que el Visual Basic muestre un error cuando vea variables no declaradas, puedes poner esto al inicio de cada módulo.

          Option Explicit

 Espero que estos trucos te sirvan, porque a mí me han servido mucho.

38
¿Te ha gustado el artículo?

Si quieres saber más y estar al día de mis reflexiones, suscríbete a mi blog y sé el primero en recibir las nuevas publicaciones en tu correo electrónico.

  1. Nuevo
    #46
    19/10/22 20:48
    Por si le interesa a alguien, adapté la función  GetColumnLetter para que funcione con columnas de hasta 3 letras. Acá va el código:

    Function GetColumnLetter(ByVal n As Integer) As String
     
        'Esta funcion determina la letra de una columna a partir del numero de columna entregado (n).
        'El codigo funciona con columnas de hasta tres letras (A, B, C, ..., ZZX, ZZY, ZZZ).
        
        'Se calculan los factores de la ecuacion n = n1 * 26^2 + n2 * 26 + n3
            Dim n1, n2, n3 As Integer
            n3 = (n - 1) Mod 26 + 1
            n2 = ((n - n3) / 26 - 1) Mod 26 + 1
            n1 = (n - n3 - n2 * 26) / 26 ^ 2
        
        'Se obtienen las letras asociadas a los factores
            Dim Axx, xAx, xxA As String
            Axx = Chr(n1 + 64) 'Letra izquierda
            xAx = Chr(n2 + 64) 'Letra intermedia
            xxA = Chr(n3 + 64) 'Letra derecha
        
        'Se unen las letras de la columna <n>
            If 0 < n And n <= 26 Then
                GetColumnLetter = xxA
            ElseIf 26 < n And n <= 702 Then
                GetColumnLetter = xAx & xxA
            ElseIf 702 < n And n <= 18278 Then
                GetColumnLetter = Axx & xAx & xxA
            Else
                GetColumnLetter = "ERROR"
            End If
        
    End Function 
  2. en respuesta a Jimy Mendoza
    -
    Top 100
    #43
    28/12/20 22:02
    Es igual s'olo que al responder una pregunta no actualizas el arreglo Respuestas() sino que actualizas la hoja de Excel.
    Y al pasar a la siguiente pregunta debes usar setfocus para colocar el cursor en el control donde debe estar para responder la siguiente pregunta.

    NombreDeControl.SetFocus

    No necesitas dos botones, con uno basta.  Cuando mucho podr'ias hacer un boton para devolverte a la pregunta anterior, cuidando que no te pases de la primera pregunta.
    Tener la minima cantidad de controles sirve para dos cosas:
    * Para evitar desperdicio de memoria, desperdicio de poder de procesamiento y reducir tiempo de carga.
    * Para facilitar la depuracion de programa

    Si tu proyecto fuera m'as complicado, tu c'odigo deberia tener el codigo separado en dos.  Uno que realiza el procesamiento, y otro que maneja la interfaz grafica o intervaz de usuario.  De esta manera no importa si la interfaz grafica cambia, el codigo que escribiste no se desecha.  La hoja de Excel tambi'en puede considerarse interfaz grafica.

    Ademas, las hojas de excel cambian,  Los datos no siempre van en el mismo lugar.  A veces los datos van en una columna y luego se les ocurre cambiar.  Y a veces los encabezados van en filas distintas. Tu codigo debe tener una prevision para ello.  Asi te evitas molesto mantenimiento.

    A veces lo mejor es usar programacin orientada a objetos y hacer una clase para manejar cada tipo de archivo.  Entonces si tenias un archivo con datos de empleados, y otro con respuestas de empleados, creas dos modulos de clase.  Para ello puedes ver el post de  programacin orientada a objetos .

    Para hacertelo mas claro, imagina que vas a programar un videojuego de coches.  Puedes usar un programa para administrar todos los coches y eso es muy complicado. O puedes crear una clase Coche, de modo que cada objeto maneja los procesos de acelerar, frenar, girar, y para cada coche vas a tener propiedades como velocidad, cantidad de combustible, ubicacion en la pista, etc.  Entonces programas una clase y al crear los objetos coches, cada uno tendra internamente sus variables distintas.  El c'odigo de un coche sirve para controlarlos a todos.

    Si diseñas bien los objetos (diseñarlos para que sean fáciles de usar toma tiempo y da pereza) el mantenimiento se vuelve muy fácil.  Claro, estoy hablando de proyectos de mediana complejidad.

    Otra cosa que necesitas es diseñar tu encuesta a prueba de usuarios.  Habrá quienes quieran alegar que la macro ha fallado. Sólo puede fallar si la fecha no usa formato americano MM/DD/YYYY o si el punto no es el símbolo decimal.  Si la macro arranca y alguna de estas dos cosas no funciona, entonces puedes hacer que la macro te envíe un correo alertando de la situacion.

    Tambien debes evitar que los usuarios manipulen la hoja.
    Puedes experimentar con esto.
    https://bettersolutions.com/vba/userforms/modeless.htm
    Eso si siempre recuerda dejar una copia de la macro donde el usuario si pueda manipular la hoja para que puedas hacer cambios.
    Habrá usuarios traviesos que querran meterse a ver el código, asi que tendrás que poner password al proyecto.

    Cuando tienes usuarios, muchas cosas puede pasar y a veces son un dolor de cabeza parati o para los jefes.



  3. en respuesta a Comstar
    -
    #42
    28/12/20 21:03
    pues no realmente.

    si tengo un user form creado desde visual basic y en este tengo dos botones, uno que da comienzo a la encuesta y otro que guarda la respuesta en una celda en especifico.

    pero quiero que al guardar una respuesta en automático me cambie la pregunta y guarde la siguiente respuesta en una celda diferente.
  4. en respuesta a Jimy Mendoza
    -
    Top 100
    #41
    27/12/20 22:42
    Estoy asumiendo que no usas forms (ventanas), ni tampoco message box (comando msgbox), sino que los botones están puestos en la hoja de Excel directamente.
    Seguro vas a necesitar alguna manera de resetear la encuesta. Imagino que va a ser ejecutando una macro al abrir el archivo.
    Entonces vas a crear un módulo y no un form.
    Las variables que vayas a usar deben declararse al puro inicio, antes de cualquier SUB o FUNCTION.  Eso hace que a nivel de módulo tengas variables globales compartidas por todos los SUB y functions.

    Para ejecutar al arrancar, necesitas crear el siguiente sub en el objeto de la hoja de Excel, y no en el módulo que creaste.
     
    Private Sub Workbook_Open()
    End Sub
     
    Al poner código en ese SUB vas a inicializar todas las variables y celdas de la encuesta.  Imagino que desplegar la primera pregunta va a ser parte de este proceso.
    Vas a necesitar algún tipo de variable puntero para saber que pregunta estás respondiendo.  Al responder una pregunta con un botón, pasas a la siguiente, y si ya terminó, entonces salvas el archivo, y cierras la encuesta.  Eso significa que cada botón de respuesta debe anotar la respuesta correspondiente en una celda o un arreglo. Y debe remitir a un SUB que lleva a cabo la verificación de si hay siguiente botón o si ya terminó.

    En el objeto de la hoja de Excel

    Private Sub Workbook_Open()
    InicializarPreguntas
    End Sub

    En el módulo...

    Const CantidadPreguntasEncuesta = 10
    Public PreguntaActual as Integer
    Dim Respuestas(10) 

    Sub InicializarPreguntas
     PreguntaActual = 1
     DesplegarPregunta 1
    End Sub

    Sub DesplegarPregunta(NumeroDePregunta)
    'Agrega codigo aqui
    End Sub

    Sub BotonRespuesta
     'Escribe codigo para encontrar el valor de la respuesta, y colocalo en la variable valor.
     Respuestas(PreguntaActual) = valor 
     If  PreguntaActual =  CantidadPreguntasEncuesta then
        'Código al terminar la encuesta
     Else
        PreguntaActual = PreguntaActual +1
     Endif
    End Sub
      
    ¿Contesta tu pregunta?

Cookies en rankia.com

Utilizamos cookies propias y de terceros con finalidades analíticas y para mostrarte publicidad relacionada con tus preferencias a partir de tus hábitos de navegación y tu perfil. Puedes configurar o rechazar las cookies haciendo click en “Configuración de cookies”. También puedes aceptar todas las cookies pulsando el botón “Aceptar”. Para más información puedes visitar nuestra política de cookies.

Configurar
Rechazar todas
Aceptar